home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / mac / files / dsp / 56000tar.z / 56000tar / 56000 / fft / fftr2d.asm < prev    next >
Assembly Source File  |  1991-11-25  |  4KB  |  106 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Radix 2, In-Place, Decimation-In-Time FFT
  7. ; (using DSP56001 Y Data ROM sine-cosine tables).
  8. ; 
  9. ; Last Update 08 Aug 86   Version 1.0
  10. ;
  11. fftr2d  macro   points,data,coef,table
  12. fftr2d  ident   1,0
  13. ;
  14. ; Radix 2 Decimation in Time In-Place Fast Fourier Transform Routine
  15. ;
  16. ;    Complex input and output data
  17. ;        Real data in X memory
  18. ;        Imaginary data in Y memory
  19. ;    Normally ordered input data
  20. ;    Bit reversed output data
  21. ;       Coefficient lookup table
  22. ;        Full cycle sinewave in Y memory
  23. ;       Coefficient table can be generated by "sinewave" macro.
  24. ;
  25. ;       This FFT version can directly use the sinewave table stored
  26. ;       in the DSP56001 Y Data ROM for up to 256 point complex FFTs.
  27. ;
  28. ; Macro Call - fftr2d   points,data,coef,table
  29. ;
  30. ;       points     number of points (2-32768, power of 2)
  31. ;       data       starting address of data buffer
  32. ;       coef       starting address of sinewave table
  33. ;       table      size of sinewave table
  34. ;
  35. ; Alters Data ALU Registers
  36. ;       x1      x0      y1      y0
  37. ;       a2      a1      a0      a
  38. ;       b2      b1      b0      b
  39. ;
  40. ; Alters Address Registers
  41. ;       r0      n0      m0
  42. ;       r1      n1      m1
  43. ;               n2
  44. ;
  45. ;       r4      n4      m4
  46. ;       r5      n5      m5
  47. ;       r6      n6      m6
  48. ;       r7      n7      m7
  49. ;
  50. ; Alters Program Control Registers
  51. ;       pc      sr
  52. ;
  53. ; Uses 6 locations on System Stack
  54. ;
  55. ; Latest Revision - August 8, 1986
  56. ;
  57.         page
  58.         move    #points/2,n0    ;initialize butterflies per group
  59.         move    #1,n2           ;initialize groups per pass
  60.         move    #table/4,n6     ;initialize C pointer offset
  61.         move    n6,n7
  62.         move    #-1,m0          ;initialize A and B address modifiers
  63.         move    m0,m1           ;for linear addressing
  64.         move    m0,m4
  65.         move    m0,m5
  66.         move    m0,m7
  67.         move    #0,m6           ;initialize C address modifier for
  68.                                 ;reverse carry (bit-reversed) addressing
  69. ;
  70. ; Perform all FFT passes with triple nested DO loop
  71. ;
  72.         do      #@cvi(@log(points)/@log(2)+0.5),_end_pass
  73.         move    #data,r0        ;initialize A input pointer
  74.         move    r0,r4           ;initialize A output pointer
  75.         lua     (r0)+n0,r1      ;initialize B input pointer
  76.         move    #coef,r6        ;initialize C input pointer
  77.         lua     (r1)-,r5        ;initialize B output pointer
  78.         move    n0,n1           ;initialize pointer offsets
  79.         move    n0,n4
  80.         move    n0,n5
  81.  
  82.         do      n2,_end_grp
  83.         move    r6,r7           ;get sine pointer
  84.         move    x:(r1),x1       y:(r6)+n6,y0    ;lookup sine value
  85.         move    x:(r5),a        y:(r0),b        ;preload data
  86.         move    y:(r7+n7),x0            ;lookup cosine value
  87.  
  88.  
  89.         do      n0,_end_bfy     ;Radix 2 DIT butterfly kernel
  90.         mac     -x1,y0,b                        y:(r1)+,y1
  91.         macr    x0,y1,b         a,x:(r5)+       y:(r0),a
  92.         subl    b,a             x:(r0),b        b,y:(r4)
  93.         mac     x1,x0,b         x:(r0)+,a       a,y:(r5)
  94.         macr    y1,y0,b         x:(r1),x1
  95.         subl    b,a             b,x:(r4)+       y:(r0),b
  96. _end_bfy
  97.         move    a,x:(r5)+n5     y:(r1)+n1,y1    ;update A and B pointers
  98.         move    x:(r0)+n0,x1    y:(r4)+n4,y1
  99. _end_grp
  100.         move    n0,b1
  101.         lsr     b       n2,a1   ;divide butterflies per group by two
  102.         lsl     a       b1,n0   ;multiply groups per pass by two
  103.         move    a1,n2
  104. _end_pass
  105.         endm
  106.